爱华网在用VBA批量操作Excel工作表单元格区域时，会遇到需要将单元格区域转换为VBA数组。同样，当需要将VBA数组输出到单元格区域时，也会遇到类似的转换。本文将对VBA数组与单元格区域的相互转换进行介绍。
VBA数组与单元格区域――工具/原料ExcelVBAVBA数组与单元格区域――方法/步骤
VBA数组与单元格区域 1、
单元格区域：指至少包含两个单元格的区域，单一单元格不属于单元格区域。
如下图所示
VBA数组与单元格区域 2、
一维水平数组：指数组的值在Excel单元格区域中水平输出，也就是按Excel列的方向输出。如下图所示
VBA数组与单元格区域 3、
一维垂直数组：指数组的值在Excel单元格区域中垂直输出，也就是按Excel行的方向输出。如下图所示
VBA数组与单元格区域 4、
当将单元格区域转换为VBA数组时，该数组变量必须是Variant类型，生成的数组是二维数组，下界是1，不受Option Base语句的影响。二维是先垂直后水平，第一维是单元格区域的行方向，第二维是单元格区域的列方向。如下所示：
Sub xyf()
'定义一个变量用于存放单元格区域的值
'未指定类型默认为Variant类型
Dim arr
arr = Range("a1:a2")
'也可以先定义一个Variant类型的动态数组变量
Dim arr1()
arr1 = Range("a1:a2")
'生成的数组的维数为(1 to 2,1 to 1)
End Sub
如下图所示
VBA数组与单元格区域_vba数组
VBA数组与单元格区域 5、
由Array函数生成的数组是一维水平数组，可以直接赋值给水平的单元格区域。如下所示：
Sub xyf()
Dim arr()
arr = Array(1, 2, 3)
Range("a1:c1") = arr
End Sub
如下图所示
VBA数组与单元格区域 6、
由于将单元格区域转换为VBA数组时，产生的数组是二维数组，而内置的VBA数组函数都是针对一维数组，所以需要将二维数组降维转换为一维数组。
VBA数组与单元格区域 7、
当将单列多行的单元格区域赋值给数组变量后，可以用Application.WorksheetFunction.Transpose转置降为一维水平数组。如下所示：
Sub xyf()
Dim arr()
'以下语句产生二维的arr(1 to 8,1 to 1)数组
arr = Range("a1:a8")
'通过转置降为一维的arr(1 to 8) 数组
arr = Application.WorksheetFunction.Transpose(arr)
End Sub
如下图所示
VBA数组与单元格区域_vba数组
VBA数组与单元格区域 8、
当将单行多列的单元格区域赋值给数组变量后，可以两次使用Application.WorksheetFunction.Transpose将数组降为一维水平数组。如下所示：
Sub xyf()
Dim arr()
'以下语句产生二维的arr(1 to 1,1 to 3)数组
arr = Range("a1:c1")
'通过两次转置降为一维的arr(1 to 3) 数组
arr = Application.WorksheetFunction.Transpose(Application.WorksheetFunction.Transpose(arr))
End Sub
如下图所示
VBA数组与单元格区域 9、
当将多行多列的单元格区域赋值给数组变量后，可以用Application.WorksheetFunction.Index函数的行参数将二维数组的每行转换为一维水平数组，如下所示：
Sub xyf()
Dim arr()
Dim arrTemp()
'以下语句产生二维的arr(1 to 5,1 to 3)数组
arr = Range("a1:c5")
'定义一个与arr数组一维尺寸相同的一维数组变量用于存放提取出来的每行一维数组的结果
ReDim arrTemp(1 To UBound(arr))
For i = 1 To UBound(arr)
'Application.WorksheetFunction.Index函数的第二参数指定行数生成一维数组
arrTemp(i) = Join(Application.WorksheetFunction.Index(arr, i), ",")
Next
End Sub
VBA数组与单元格区域 10、
Application.WorksheetFunction.Index函数将二维数组降维时，只有通过行参数才可以直接降维，通过列参数不能直接降维，如下所示：
Sub xyf()
Dim arr()
Dim arrTemp()
'以下语句产生二维的arr(1 to 5,1 to 3)数组
arr = Range("a1:c5")
'生成一维数组(1 to 3)
arrTemp = Application.WorksheetFunction.Index(arr, 1)
'生成一维数组(1 to 3)
arrTemp = Application.WorksheetFunction.Index(arr, 1, 0)
'通过Index的列参数不能降维 , arrTemp还是二维数组(1 to 5,1 to 1)
arrTemp = Application.WorksheetFunction.Index(arr, 0, 1)
End Sub
VBA数组与单元格区域――注意事项如果这篇文章对您有所帮助，请为这篇文章投票，谢谢。
